support/android/apk/settings.gradle.kts


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

import java.util.Properties

pluginManagement {
    repositories {
        google()
        mavenCentral()
        gradlePluginPortal()
    }
}

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
    }
}

include(":servoapp")

val userPropertiesFile = File("user.properties")
if (userPropertiesFile.exists()) {
    println("Loading user.properties")
    val props = Properties()
    userPropertiesFile.inputStream().use {
        props.load(it)
    }
    props.forEach { (key, value) ->
        println("$key = $value")
        gradle.extra.set(key!!.toString(), value);
    }
    if (props.containsKey("servoViewLocal")) {
        println("Using local build of servoview")
        include (":servoview-local")
        project(":servoview-local").projectDir = File("servoview-local")
    } else {
        include(":servoview")
    }
} else {
    include(":servoview")
}